Animation : Un cercle roulant

Voici une petite animation où le déplacement de chaque balle sur les rayons du disque donne le mouvement d'un cercle de rayon deux fois plus petit roulant à l'intérieur du cercle initial.

animation
Chargement...

animCercle.mp

%@ Maxime Chupin
%@ 4 février 2017
 
prologues := 3;
outputtemplate := "svg/%j-%c.svg";
outputformat := "svg";
 
% unité
u:=1cm;
%rayon cercle
r:=5u;
 
% nombre de quartier
numeric n;
n := 16;
 
% l'origine
pair O;
O :=(0,0);
 
 
% le fond
picture fond;
numeric angle;
fond = image(
  fill fullcircle scaled 2r withcolor black;
  for i:= 0 upto n-1:
  angle := (360.0/n)*i;
  draw (-r*cosd(angle),-r*sind(angle)) -- (r*cosd(angle),r*sind(angle)) withcolor white;
endfor;
);
 
% les balles
% rayon balle
rb := 0.3u;
def balle =
  fullcircle scaled 2rb
enddef;
 
% les différentes images
for j:= 0 upto 359:
  beginfig(j);
    draw fond;
    for i:=0 upto n-1:
      angle := (360.0/n)*i;
      fill balle shifted ((r-rb)*sind(angle+j),0) rotatedaround(O,angle) withcolor white;
    endfor;
  endfig;
endfor;
end.
 

Table des matières